Win7下VHD文件右键增强实现代码(vbs+注册表)

Dim Args
Set Args = WScript.Arguments
TranArgs = " "
For i = 0 To Args.Count - 1
 TranArgs = TranArgs & """" & Args(i) & """" & " "
Next

If Args(0) <> "-hFlag" Then
 If Args(0) <> "-hWind" Then
  CreateObject("Shell.Application").ShellExecute "wscript.exe", _
   """" & WScript.ScriptFullName & """" & " -hWind" & TranArgs, "", "runas", 1
  WScript.Quit(5)
 Else
  CreateObject("Wscript.Shell").Run "cscript.exe " & _
   """" & Wscript.ScriptFullName & """" & Replace(TranArgs, "-hWind", "-hFlag"), 0, TRUE
  WScript.Quit(1)
 End If
Else
 'Add Your Codes
 Dim objShell, objExec
 Set objShell = WScript.CreateObject("Wscript.Shell")
 Set objExec = objShell.Exec("c:\windows\system32\diskpart.exe")

 objExec.StdIn.WriteLine "select vdisk file=""" & WScript.Arguments(2) & """"

 Select Case Args(1)
  Case "/M"
   objExec.StdIn.WriteLine "attach vdisk"
   objExec.StdIn.WriteLine "exit"
   WScript.Quit(0)

  Case "/D"
   objExec.StdIn.WriteLine "detach vdisk"
   objExec.StdIn.WriteLine "exit"
   WScript.Quit(0)

  Case Else
   'other
   WScript.Quit(0)
 End Select

 WScript.Quit(0)
End If